Muscle Development

Muscle Development preview image

1 collaborator

Uri_dolphin3 Uri Wilensky (Author)

Tags

biology 

Tagged by Reuven M. Lerner over 10 years ago

Model group CCL | Visible to everyone | Changeable by group members (CCL)
Model was written in NetLogo 5.0.4 • Viewed 709 times • Downloaded 68 times • Run 0 times
Download the 'Muscle Development' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This is an exercise physiology model. It is intended to help you understand the factors involved in generating the appropriate hormonal balance to develop muscle from weight lifting. These factors include:

Frequency: How often you lift weights must be managed appropriately in order to see gains in muscle mass. If you lift too frequently, you will not have time to recover and then rebuild stronger muscles. If you fail to lift frequently enough, there will not be enough stimuli to elicit long term gains in muscle.

Sleep: The body performs most of its recovery while sleeping. If you don't get enough sleep, you will not be providing enough opportunity for recovery, so you will find it difficult to gain muscle.

Intensity: How hard you works in the weight room affects how effective you are at recruiting all of your muscle fibers. The greater the number of fibers recruited, the greater the growth stimulus, assuming appropriate recovery is provided for.

Genetic: The ratio of slow twitch to fast twitch muscle fibers plays a large role in how much muscle an individual is capable of developing. Someone with a majority of fibers that exhibit slow twitch characteristics will have high endurance, but the potential to develop only moderate muscle mass. An individual with a majority of fibers with fast twitch characteristics will have the potential to develop considerable muscle mass, but low endurance.

Diet: A poor diet can prevent muscle growth. In this model we assume perfect diet.

All five of these factors must be understood and put into balance with one another in order to achieve optimal muscular development. The appropriate combination is highly dependent on the individual and their current, unique state. It will change over time.

HOW IT WORKS

Ultimately, the effects of resistance training occur as a result of the hormonal responses it elicits from the body. The hormones essential to muscle development can be separated into two broad classes: catabolic hormones and anabolic hormones. Catabolic hormones break down the muscle fiber to prepare it to be rebuilt stronger by the anabolic hormones. Note: catabolic hormones play a vital role, as muscle fibers must be broken down before they can be built back up.

This model attempts to simulate these effects with a cross sectional portrayal of a muscle at the level of the muscle fibers. When the observer activates a muscle fiber through resistance training, the fiber releases a chemical signal that results in a surge of hormones at the location of the fiber. These hormones affect the fiber development as mentioned above and will dissipate over time.

The circles represent muscle fibers. The background they appear against may be thought of as the cellular fluid that contains the anabolic and catabolic hormones. The brighter the green, the more anabolic (muscle building) the environment. The brighter the yellow, the more catabolic (muscle destroying) the environment.

HOW TO USE IT

Buttons: SETUP: Sets up the model GO: Runs the model

Switches: LIFT?: Decides whether or not the person is actively weight lifting

Sliders: INTENSITY: How hard the lifter is working. The greater the intensity, the greater the number of muscle fibers that will be fatigued each workout session. HOURS-OF-SLEEP: The amount of sleep a person gets affects how quickly the body breaks down the hormones.

DAYS-BETWEEN-WORKOUTS: The frequency of the workouts effects how much time the body has to recover and then over-compensate from the last workout %-SLOW-TWITCH-FIBERS: How likely each fiber is to possess slow twitch characteristics.

Plots: MUSCLE DEVELOPMENT VS. TIME: The sum of all fiber sizes over time HORMONES VS. TIME: The average hormone content near each fiber

THINGS TO TRY

Steps one through three should be run with %-SLOW-TWITCH slider set to 50.

  1. Run the model at its default settings. What eventually happens to the amount of muscle mass? Why?

  2. Overtraining occurs when the body is not allowed to recover completely from the last exercise session before being trained again. This causes stagnation of muscular development, and in extreme cases, muscle loss. What types of conditions can lead to overtraining? What is the best way to recover from overtraining? What steps can be taken to avoid it?

  3. Many undertake weight training in an effort to build the maximum amount of muscle they are capable of. Find the best method for achieving this. How must it vary over time? Why is it important to take one's current level of condition into consideration when choosing a resistance training program?

  4. An issue rarely addressed in conventional training is that of genetic ability. A major factor effecting this the proportion of slow twitch vs. fast twitch muscle fibers a person possesses. Slow twitch fibers provide for greater endurance, fast twitch greater strength and size.

Attempt to obtain maximal muscular development with the %-SLOW-TWITCH slider set at 90% and then 10%. How do the results one can obtain vary with genetic ability? Training methods? What does this suggest about the average person following the routines of genetically gifted professional bodybuilders?

EXTENDING THE MODEL

  1. In order to ensure you have achieved maximum muscular development, add a pen named "max-muscle" to the "Muscle Development" plot. Now modify the DO-PLOTTING procedure to use the "max-muscle" pen to plot the sum of the MAX-SIZE value of all the muscle fibers.

  2. Nutritional quality can have a major influence on the results obtained from training. Modify the model to allow for this influence. Add a NUTRIENT variable to the MUSCLE-FIBER breed. Add a NUTRITIONAL-QUALITY slider to the model. Now modify the GO procedure to call a OBTAIN-NUTRITION function that releases nutrients into the patches. Finally, alter the GROW procedure to use the available nutrients when adding size to a muscle fiber.

  3. Real life creates many inconsistencies in the average person's strength training program. Add a variance function to the model that randomly generates nights of less sleep and extra rest days between workouts to reflect these inconsistencies. Add a switch to allow the user to turn this variance on or off. Add a slider to allow the user to adjust the level of variance. What effect do these inconsistencies have on muscular development?

THINGS TO NOTICE

The human body is an incredibly complex system. In order to simulate the piece of it in which we are interested, assumptions have been made about the behavior of other pieces. This can be seen in the hard-coding of various parameters, such as the hormone limits and the maximum muscle fiber sizes. These assumptions allow us to focus upon gaining an understanding of the overall process of muscle development without becoming burdened with excessive information.

NETLOGO FEATURES

Note the use of the repeat primitive and %-SLOW-TWITCH-FIBERS variable in the new-muscle-fibers procedure to generate a normal distribution of the maximum muscle fiber sizes centered at a median influenced by the %-SLOW-TWITCH-FIBERS value.

Note the use of the log primitive in the procedures which regulate hormonal release and balance. This allows us to more closely mimic the natural tendency for each additional unit of a biological component to illicit less of an adaptive change from the system than the one before it.

Note the use of the rgb primitive in the regulate-hormones procedure to color patches based on hormone quantities and provide a smooth visual transition from an anabolic to a catabolic state.

CREDITS AND REFERENCES

Original implementation: Scott Styles, for the Center for Connected Learning and Computer-Based Modeling.

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

COPYRIGHT AND LICENSE

Copyright 2002 Uri Wilensky.

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

This model was created as part of the projects: PARTICIPATORY SIMULATIONS: NETWORK-BASED DESIGN FOR SYSTEMS LEARNING IN CLASSROOMS and/or INTEGRATED SIMULATION AND MODELING ENVIRONMENT. The project gratefully acknowledges the support of the National Science Foundation (REPP & ROLE programs) -- grant numbers REC #9814682 and REC-0126227.

Comments and Questions

Units (Question)

Does anybody know what are the units of time in this model, the units of muscle mass and if the model refers to all the muscles or a particular part. I am using this model for my Biology IA as I am a IB student and this information would help me a lot

Posted 5 months ago

Click to Run Model

breed [ muscle-fibers muscle-fiber ]

muscle-fibers-own [
  fiber-size   ;; different from built-in "size" because it uses different units
  max-size
]

patches-own [
  anabolic-hormone  ;; muscle building hormone
  catabolic-hormone ;; muscle breaking down hormone
]

globals [
  muscle-mass  ;; stores sum of muscle-fiber sizes
  ;; hormone bounds to ensure a realistic environment
  anabolic-hormone-max
  anabolic-hormone-min
  catabolic-hormone-max
  catabolic-hormone-min
  ;; the rate at which hormones from one fiber diffuse to others
  hormone-diffuse-rate
]

to setup
  ca
  set-default-shape muscle-fibers "circle"
  initialize-hormones
  new-muscle-fibers
  set muscle-mass sum [fiber-size] of muscle-fibers
  reset-ticks
end 

to initialize-hormones
  ;; constants chosen align the model time frame for muscle development
  ;; with realistic values
  set hormone-diffuse-rate 0.75
  ask patches [
    set anabolic-hormone-max 200
    set catabolic-hormone-max 250
    set anabolic-hormone-min 50
    set catabolic-hormone-min 52
    set anabolic-hormone 50
    set catabolic-hormone 52
  ]
  regulate-hormones
end 

to new-muscle-fibers
  ask patches [
    sprout-muscle-fibers 1 [
      set max-size 4
      ;; create a normalized distribution of maximum muscle fiber sizes
      ;; with median dependent on % of slow twitch fibers.
      repeat 20  [
        if random-float 100 > %-slow-twitch-fibers [
          set max-size max-size + 1
        ]
      ]
      ;; provide non-uniform starting sizes for varied results, everyone's different
      set fiber-size (0.2 + random-float 0.4) * max-size
      regulate-muscle-fibers
    ]
  ]
end 

to go
  ;; note the use of the LOG primitive in the procedures called below
  ;; to simulate a natural system's tendency to adapt less and less
  ;; to each additional unit of some biological substance
  perform-daily-activity
  if lift? and (ticks mod days-between-workouts = 0)
    [ lift-weights ]
  sleep
  regulate-hormones
  develop-muscle
  set muscle-mass sum [fiber-size] of muscle-fibers
  tick
end 

to perform-daily-activity
  ;; simulate hormonal effect of lifestyle
  ;; activities like watching TV and working
  ask muscle-fibers [
    set catabolic-hormone catabolic-hormone + 2.0 * (log fiber-size 10)
    set anabolic-hormone anabolic-hormone + 2.5 * (log fiber-size 10)
  ]
end 

to lift-weights
  ;; simulate hormonal effect of weight training
  ask muscle-fibers [
    if( random-float 1.0 < intensity / 100 * intensity / 100 ) [
      set anabolic-hormone anabolic-hormone + (log fiber-size 10) * 55
      set catabolic-hormone catabolic-hormone + (log fiber-size 10) * 44
    ]
  ]
end 

to sleep
  ;; simulate hormonal effect of sleeping
  ask patches [
    set catabolic-hormone catabolic-hormone - 0.5 * (log catabolic-hormone 10) * hours-of-sleep
    set anabolic-hormone anabolic-hormone - 0.48 * (log anabolic-hormone 10) * hours-of-sleep
  ]
end 

to develop-muscle
  ask muscle-fibers [
    grow
    regulate-muscle-fibers
  ]
end 

to grow  ;; turtle procedure
  ;; catabolic hormones must prepare the fibers for growth before the
  ;; anabolic hormones may add mass to the fibers
  set fiber-size (fiber-size - 0.20 * (log catabolic-hormone 10))
  set fiber-size (fiber-size + 0.20 * min (list (log anabolic-hormone 10)
                                                (1.05 * log catabolic-hormone 10)))
end 

to regulate-muscle-fibers ;;turtle procedure
  ;; simulate the body's natural limits on minimum and maximum fiber sizes
  if (fiber-size  < 1) [ set fiber-size 1 ]
  if (fiber-size > max-size) [ set fiber-size max-size ]
  set color scale-color red fiber-size (-0.5 * max-size) (3 * max-size)
  ;; base the visible size of the turtle on its fiber-size
  set size max list 0.2 (min list 1 (fiber-size / 20))
end 

to regulate-hormones ;;patch procedure
  ;; hormones spread to neighboring fibers
  diffuse anabolic-hormone hormone-diffuse-rate
  diffuse catabolic-hormone hormone-diffuse-rate
  ;; if there are to many or to few hormones in an area,
  ;; the body will try very hard to restore a balance
  ask patches [
    set anabolic-hormone min (list anabolic-hormone anabolic-hormone-max)
    set anabolic-hormone max (list anabolic-hormone anabolic-hormone-min)
    set catabolic-hormone min (list catabolic-hormone catabolic-hormone-max)
    set catabolic-hormone max (list catabolic-hormone catabolic-hormone-min)
    ;;color patches based on hormone concentrations
    set pcolor approximate-rgb ((catabolic-hormone / catabolic-hormone-max) * 255)
                   ((anabolic-hormone / anabolic-hormone-max)  * 255)
                   0
  ]
end 


; Copyright 2002 Uri Wilensky.
; See Info tab for full copyright and license.

There are 10 versions of this model.

Uploaded by When Description Download
Uri Wilensky almost 11 years ago Updated to NetLogo 5.0.4 Download this version
Uri Wilensky over 11 years ago Updated version tag Download this version
Uri Wilensky over 11 years ago Updated to version from NetLogo 5.0.3 distribution Download this version
Uri Wilensky about 12 years ago Updated to NetLogo 5.0 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Updated from NetLogo 4.1 Download this version
Uri Wilensky almost 14 years ago Model from NetLogo distribution Download this version
Uri Wilensky almost 14 years ago Muscle Development Download this version

Attached files

File Type Description Last updated
Muscle Development.png preview Preview for 'Muscle Development' almost 11 years ago, by Uri Wilensky Download

This model does not have any ancestors.

This model does not have any descendants.