Mouse Up Example

turtles-own [ grabber ]

to startup
  setup
  hubnet-set-client-interface "COMPUTER" []
  hubnet-reset
end 

to setup
  clear-all
  ask n-of 15 patches [ sprout 1 [ pd  set grabber "" ] ]
end 

to go
  every 0.1
  [
    listen-clients
    display
  ]
end 

to listen-clients
  while [ hubnet-message-waiting? ]
  [
    hubnet-fetch-message
    if not hubnet-enter-message? and not hubnet-exit-message?
    [ execute-command hubnet-message-tag hubnet-message ]
  ]
end 

to execute-command [tag msg]
  if tag = "View"
  [ grab-turtle hubnet-message-source msg ]
  if tag = "Mouse Up"
  [ drop-turtle hubnet-message-source msg ]
end 

to grab-turtle [name coords]
  let clicked-patch patch first coords last coords
  let my-turtle one-of (turtles-on clicked-patch) with [grabber = ""]
  if my-turtle != nobody
  [
    ask my-turtle [ set grabber name ]
  ]
end 

to drop-turtle [name coords]
  ask turtles with [grabber = name] 
  [ setxy first coords last coords
    set grabber "" ]
end