Risk Quantum Simulator I - Nuclear War

Risk Quantum Simulator I - Nuclear War preview image

1 collaborator

Tags

complex quantum systems 

Tagged by Carlos Pedro S. Gonçalves over 11 years ago

quantum computation 

Tagged by Carlos Pedro S. Gonçalves over 11 years ago

risk mathematics 

Tagged by Carlos Pedro S. Gonçalves over 11 years ago

Model group Risk Mathematics | Visible to everyone | Changeable by group members (Risk Mathematics)
Model was written in NetLogo 5.0.2 • Viewed 1695 times • Downloaded 38 times • Run 0 times
Download the 'Risk Quantum Simulator I - Nuclear War' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


THE MODEL

This is a risk quantum simulator that addresses the evolution of the political relations between two countries leading up to the threat of nuclear war, introduced in the article:

Gon_alves, C.P. (2012). "Risk Mathematics and Quantum Games on Quantum Risk Structures - A Nuclear War Scenario Game" arXiv:1211.6683 [physics.soc-ph] (http://arxiv.org/abs/1211.6683).

The model was built for both research and use in the classroom in roleplaying sessions on decision making techniques and risk analysis, as well as in the building up of scenario analysis.

The model applies quantum game theory with coupled stochastic chaotic gates leading to a coevolution of political scenarios, that involve increased social, military and political tension between the two countries.

There are eight main risk factors are addressed in the model:

  • Growing tensions: this corresponds to situations that lead to growing political tensions between the two countries linked to conflicts of interest, possible diplomatic incidents, economic and political competition with possible military fallout.

  • Political turmoil: this includes internal and external political turmoil involving the two countries tension issues, it can lead to both demonstrations and actions of supporters of each country in the streets, and political instability due to political statements and actions undertaken by both countries.

  • Failure to negotiate: this corresponds to failure of both countries in finding an aggreement on key issues, that may prevent the countries from communicating and finding diplomatic sollutions to their grievances.

  • Civil unrest: when people take to the streets in protest on both internal problems and problems involving both countries, it also includes the possibility of social disorder and possible escalade in street violence linked to key problems that divide the two countries.

  • Conflict breakout: this corresponds to a conflict breakout between the two countries involving conventional non-nuclear arsenal.

  • Nuclear threat escalation: escalation of nuclear threat, that is escalation in the threat of both countries using their nuclear arsenal.

  • UN intervention/mediation: this corresponds to attempts of UN to influence both countries in finding common ground and mediating political negotiations between both countries, but it also entails deliberations and actions that can be taken by UN's Security Council in the case of military conflict between the two countries or of nuclear weapons being used.

  • Nuclear war: this corresponds to both countries using nuclear weapons on each other triggering a nuclear war.

The occurrence of each risk factor-related event is addressed in terms of a quantum game played on a quantum computing network, with path-dependent unitary gate updating. The quantum game framework is explained further on in the "MODEL FORMALIZATION" section below, which provides for the full model description and interpretation.

At each game round the user clicks on the button play-quantum-game, this leads to an evolution in the relations between the two countries. As each threat increases in probability of occurrence (see the next section for a proper interpretation of probabilities), the circle corresponding to the event starts to grow, whenever the threat takes place the circle turns from yellow color to red.

Simultaneously, the countries flag size also increases from its base size with the mean number of events.

The user can apply the model in a scenario event generator by registering each event in a word file and reading afterwards the sequence of what took place. Multiple simulations, ran a number of N steps can provide for a database for the occurrence of Nuclear War.

The different possible paths to Nuclear War can be enumerated and incorporated in an analysis of early warning systems.

Likewise, in a roleplaying session, the students can be divided into groups and events are relayed to them in real time, with each group assessing scenarios risk and measures.

The user and students can control six sliders, three of these relate to UN intervention parameters (the formal explanation of each of them is addressed in the next section):

UN-negotiation-eff : this is the UN negotiation effectiveness reduces the probability of the event taking place;

UN-impact : this is the impact of the UN under UN mediation, it counts as the influence of the UN upon the two countries;

UN-analysis-coupling : this slider influences the UN threat assessment and, therefore, the propensity of the UN to intervene.

The user may address the level of UN intervention and impact to see how the risk for a nuclear escalation and nuclear war changes.

Students may also change these sliders in a on-class decision interactive game.

b : this slider controls the quantum coupled logistic map that emerges as an order parameter dynamics from each risk factor's quantum evolution;

epsilon : this slider controls the coupling of the logistic map to the mean field of linked risk situations (see the next section for further details);

delta ; this slider controls the noise level in the coupled logistic map, so that there is a stochastic chaotic unitary gate selection for the quantum evolution, expressing evolutionary social, political and military conditions between the two countries.

The updating frequency of the slider allows you to slow down each model's steps so that you can visualize better the evolution of the unfolding scenarios.

The game stops when nuclear war is reached.

CREDITS AND REFERENCES

The main reference for the model is the article that provides the quantum theoretical background for the model as well as provides for the full model formalism:

Gon_alves, C.P. (2012). "Risk Mathematics and Quantum Games on Quantum Risk Structures - A Nuclear War Scenario Game" arXiv:1211.6683 [physics.soc-ph] (http://arxiv.org/abs/1211.6683).

The current model is also an integrating part of the research and teaching umbrella project under development by the author at Instituto Superior de Cincias Sociais e Polticas (ISCSP), Technical University of Lisbon:

COMPLEX QUANTUM SYSTEMS SCIENCE AND RISK MATHEMATICS (CQSSRM)

URL: https://sites.google.com/site/quantumcomplexity/

For academic reference the model should be quoted as:

Gon_alves, C.P. 2012. "Risk Simulator I - Nuclear War". CQSSRM - "Risk Simulator".

The model has been used on the author's lectures on "Decision Making Techniques" at the Masters Course in Strategy at ISCSP as a roleplaying and game theory-based scenario building tool. It has also been used in demonstrations of combined modeling and data analysis applied to geopolitical problems in the author's data analysis classes.

Other references dealing with risk mathematics and with some of the formalism introduced in arXiv:1211.6683 [physics.soc-ph] are:

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

breed [countries]
breed [events]

countries-own
[ country-id-code ]

links-own [ coupling-strength source-occurrence ]

globals [ low medium high clock ] ; coupling strength levels

events-own 
[ psi_0 psi_1 ; qubit psi(0)*|no ocurrence> + psi(1)*|occurrence>
  P-threat
  occurrence
  F ]

to setup
  ca
  set-default-shape countries "flag"
  set-default-shape events "circle"
  ask patches [set pcolor white]
  set low 0.1 * random-float 1.000
  set medium 0.1 + 0.4 * random-float 1.000
  set high 0.4 + 0.9 * random-float 1.000
  setup-events
  setup-countries
  setup-morphic-web
  setup-initial-qubit
end 

to play-quantum-game
  set clock clock + 1
  if clock mod updating-frequency = 0 
  [  
   ask events [ set color yellow ]
   update-qubits
   quantum-projections
   event-occurrences
   ask events with [occurrence = 1] [ set color red ] ]
  if [occurrence] of turtle 7 = 1 [ stop ]
end 





;;;;;;;;;;;;;;;;;;;
; GAME PROCEDURES ;
;;;;;;;;;;;;;;;;;;;

to update-qubits
  
  ask events [ set F psi_1 * b * (1 - psi_1) ]
  
  ask links [ set source-occurrence (list [ F ] of both-ends) ]
  
  ask events [ set psi_1 (1 - epsilon - delta) * F + epsilon * (1 / (sum [coupling-strength] of my-in-links)) * sum [item 0 (reduce * source-occurrence) * coupling-strength] of my-in-links + delta * random-float 1.000 ]
  
  ask events with [who != [who] of turtle 6] [ ifelse [occurrence] of turtle 6 = 1 [ set psi_1 (1 - UN-negotiation-eff) * psi_1 + UN-negotiation-eff * (1 - UN-impact) * psi_1 ] [ set psi_1 psi_1 ] ]
  
  ask events [ set psi_0 sqrt( 1 - psi_1 ^ 2 ) ]
end 

to quantum-projections
  ask events [ set P-threat psi_1 ^ 2 ]
  ask events [ set size 1 + P-threat * 3 ]
end 

to event-occurrences
  ask events [ ifelse random-float 1.000 <= P-threat [ set occurrence 1 ] [ set occurrence 0 ] ]
  ask countries [ set size 2 + mean [occurrence] of events * 12 ]
  ask turtle 6 [ if ([occurrence] of turtle 4 = 1 or [occurrence] of turtle 7 = 1) [set occurrence 1] ]
end 

;;;;;;;;;;;;;;;;;;;;
; SETUP PROCEDURES ;
;;;;;;;;;;;;;;;;;;;;

to setup-events
  create-ordered-events 8 [ fd 8 rt 180 ]
  ask events [ set color yellow ]
end 

to setup-morphic-web
  ; the user should adapt this procedure to the event list linkages that the user wants to model
  ; in the present, as an example, we use the eight events:
  
  ; 1 - Growing tensions between the two countries: turtle 0
  ; 2 - Political turmoil in country-to-country relations: turtle 1
  ; 3 - Failure to negociate: turtle 2
  ; 4 - Civil unrest: turtle 3
  ; 5 - Break out of conflict: turtle 4
  ; 6 - Nuclear threat escalation: turtle 5
  ; 7 - UN intervention/mediation: turtle 6
  ; 8 - Nuclear war scenario: turtle 7
  
  ask turtle 0 
    [ set label "growing tensions"
      create-link-to turtle 1 [ set coupling-strength medium ] ; political turmoil coupling
      create-link-to turtle 2 [ set coupling-strength medium ] ; failure to negotiate coupling
      create-link-to turtle 3 [ set coupling-strength low ] ; civil unrest coupling
      create-link-to turtle 4 [ set coupling-strength low ] ; war break out
      create-link-to turtle 7 [ set coupling-strength medium ] ] ; UN intervention/mediation coupling
    
  ask turtle 1
    [ set label "political turmoil"
      create-link-to turtle 0 [ set coupling-strength high ] ; growing tensions coupling
      create-link-to turtle 2 [ set coupling-strength high ] ; failure to negotiate coupling
      create-link-to turtle 3 [ set coupling-strength high ] ] ; civil unrest coupling

  ask turtle 2
    [ set label "failure to negociate"
      create-link-to turtle 0 [ set coupling-strength high ] ; growing tensions coupling
      create-link-to turtle 1 [ set coupling-strength high ] ; political turmoil coupling
      create-link-to turtle 3 [ set coupling-strength high ] ; civil unrest coupling
      create-link-to turtle 4 [ set coupling-strength high ] ; war break out
      create-link-to turtle 6 [ set coupling-strength high ] ] ; UN intervention/mediation coupling
  
  ask turtle 3
    [ set label "civil unrest"
      create-link-to turtle 0 [ set coupling-strength high ] ; growing tensions coupling
      create-link-to turtle 1 [ set coupling-strength high ] ; political turmoil coupling
      create-link-to turtle 4 [ set coupling-strength medium ] ; conflict break out coupling
      create-link-to turtle 6 [ set coupling-strength high ] ] ; UN intervention/mediation coupling

  ask turtle 4
    [ set label "conflict break out"
      create-link-to turtle 0 [ set coupling-strength high ] ; growing tensions coupling
      create-link-to turtle 1 [ set coupling-strength high ] ; political turmoil coupling
      create-link-to turtle 2 [ set coupling-strength high ] ; failure to negotiate coupling
      create-link-to turtle 6 [ set coupling-strength 1 ] ; UN intervention/mediation coupling
      create-link-to turtle 5 [ set coupling-strength medium ] ] ; nuclear threat escalation
  
  ask turtle 5
    [ set label "nuclear threat escalation"
      create-link-to turtle 0 [ set coupling-strength high ] ; growing tensions coupling
      create-link-to turtle 1 [ set coupling-strength high ] ; political turmoil coupling
      create-link-to turtle 2 [ set coupling-strength high ] ; failure to negotiate coupling
      create-link-to turtle 6 [ set coupling-strength 1 ] ; UN intervention/mediation coupling
      create-link-to turtle 7 [ set coupling-strength high ] ] ; nuclear war coupling
  
  ask turtle 6 [ set label "UN intervention/mediation" ]
  
  ask turtle 7 
  [ set label "nuclear war"
    create-link-to turtle 6 [ set coupling-strength 1 ] ]
  
  ask events [ set label-color black ]
end 

to setup-initial-qubit
  ask events [ set psi_0 1 set psi_1 0 set occurrence 0 ] ; no threats initially active other than...
  
  ask turtle 0 ; there is a 0.1 weight for the branch in which growing tensions begin to take hold
  [ set psi_1 sqrt(random-float 0.01000)
    set psi_0 sqrt(1 - (psi_1) ^ 2)
    set occurrence 0 ]
  
  ask events [ ask events [ set P-threat psi_1 ^ 2 ] ]
end 

to setup-countries
  ask patch -5 20
  [ sprout-countries 1
    [ set country-id-code "A"
      set color red
      set size 2
      set label country-id-code ] ]
  
  ask patch 5 20
  [ sprout-countries 1
    [ set country-id-code "B"
      set color blue
      set size 2
      set label country-id-code ] ]
  
  ask countries [ set label-color black ]
end 

There is only one version of this model, created over 11 years ago by Carlos Pedro S. Gonçalves.

Attached files

File Type Description Last updated
Risk Quantum Simulator I - Nuclear War.png preview Preview for 'Risk Quantum Simulator I - Nuclear War' almost 11 years ago, by Carlos Pedro S. Gonçalves Download

This model does not have any ancestors.

This model does not have any descendants.