Feedback Loop Example: Wildland Fire Spread

Feedback Loop Example: Wildland Fire Spread preview image

2 collaborators

Jm1_vsm James Millington (Author)
George Perry (Domain expert)

Tags

e&s_chansfeedback 

Tagged by James Millington over 11 years ago

feedback loop 

Tagged by James Millington over 11 years ago

fire 

Tagged by James Millington over 11 years ago

spatial 

Tagged by James Millington over 11 years ago

spread 

Tagged by James Millington over 11 years ago

Visible to everyone | Changeable by the author
Model was written in NetLogo 5.0 • Viewed 1065 times • Downloaded 46 times • Run 0 times
Download the 'Feedback Loop Example: Wildland Fire Spread' modelDownload this modelEmbed this model

Do you have questions or comments about this model? Ask them here! (You'll first need to log in.)


WHAT IS IT?

This model is a replication of that described by Peterson (2002) and illustrates the 'spread' feedback loop type described in Millington (2013). In spread feedback, spatial patterns influence spread processes which influence later spatial patterns and hence later spread processes. In ecology, this concept of processes being shaped by their history is known as the memory of the process (Peterson 2002). For wildland fire, memory _ and therefore feedbacks between spread and spatial pattern _ has been conceptualized as being contained in vegetation flammability as a function of time since last the fire. In this model version red patches indicate areas burned in a given time step, green patches the length of time since the last fire at that location (lighter, fire more recently).

HOW IT WORKS

The simulated environment contains vegetation, the flammability (probability of spread, pfs) of which is governed by time since last fire (tsf). In each timestep a given number of fires are ignited at randomly selected locations in the simulated environment. Fires spread to neighbouring locations determined by the vegetation flammability. The number of fires ignited in each timestep is set by the user, as is the relationship between pfs and tsf).

HOW TO USE IT

First, set the number of ignitions per timestep by moving the ignition-rate slider (larger number will result in more fires per timestep). Next, determine the relationship between tsf and pfs by moving the log-alpha and tp-max sliders. The relationship between tsf and pfs for the selected values can be observed in the TSF Curve plot by clicking setup (the number of fires per timestep will also be displayed in the ignitions monitor). See Peterson (2002, p.332) for details of how log-alpha (via alpha, the memory parameter) and tp-max influence the shape of the TSF Curve.

Click Go to run the simulation. If the model runs slowly on your machine you can try reducing the total area of the environment (right-click environment, click edit, then reduce the world-width and world-height values).

THINGS TO NOTICE

Notice how recently burned patches are less likely to burn in a given time step, and so the pattern of previous burns influences contemporary burns (with fires more likely to burn dark areas in the previous time step). The proportion of the landscape with different tsf and pfs values are shown by the histogram plots.

THINGS TO TRY

Try changing the log-alpha value (producing different values for alpha, the memory parameter) to change the TSF Curve and the ignition-rate value to change the number of ignitions per timestep. Look at how these changes influence the size of fires and how restricted they are by patterns of vegetation.

CREDITS AND REFERENCES

Millington, J.D.A. (2013) Three types of spatial feedback loop in coupled human and natural systems. Ecology and Society [URL HERE]

Peterson, G. D. (2002). Contagious disturbance, ecological memory, and the emergence of landscape pattern. Ecosystems, 5(4), 329-338.

Code licenced by James D.A. Millington (http://www.landscapemodelling.net) under a Creative Commons Attribution-Noncommercial-Share Alike 3.0 Unported License (see http://creativecommons.org/licenses/by-nc-sa/3.0/)
Model and documentation available from http://openabm.org

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;                                                                              ;;
;;       Feedback Loop Example: Wildland Fire Spread      December 2012         ;;
;;                                                                              ;;
;;  Code licenced by James D.A. Millington (http://www.landscapemodelling.net)  ;;
;;  under a Creative Commons Attribution-Noncommercial-Share Alike 3.0          ;;
;;  Unported License (see http://creativecommons.org/licenses/by-nc-sa/3.0/)    ;;
;;                                                                              ;;
;;  Model and documentation available from http://openabm.org                   ;;
;;                                                                              ;;
;;  Model used in:                                                              ;;
;;  Millington, J.D.A. (2013) Three types of spatial feedback loop in coupled   ;;
;;     human and natural systems. Ecology and Society [URL HERE]                ;;
;;                                                                              ;; 
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;


globals 
[
  alpha
  p-max
  ignitions
  fire-front
  max-tsf
]     


patches-own
[
  tsf
  pfs
]

to setup
  
  ca
  reset-ticks
  
  set alpha 10 ^ log-alpha
  set p-max 0.24
  set ignitions ignition-rate * (world-height / 100) ;this is more feasible
    
  ask patches
  [
    set tsf 1
    set pfs set-pfs tsf
    set pcolor scale-color lime tsf tp-max 0
  ]
  
  update-plots
end 

to-report set-pfs [ age ]
  
  ifelse(age > tp-max)
  [ report p-max ]
  [ report p-max * (age / tp-max) ^ alpha ] 
end 

to go
    
  ask patches [ set pcolor scale-color lime tsf tp-max 0 ]
  
  repeat ignitions
  [ ignite ]

  ask patches
  [  
    set tsf tsf + 1
    set pfs set-pfs tsf
  ]
  
  set max-tsf max [tsf] of patches
 
  tick
end 


; Code for 'ignite' procedure by George L.W. Perry, University of Auckland (http://web.env.auckland.ac.nz/people_profiles/perry_g/) 

to ignite
  
  ask one-of patches
  [
    set tsf 0
    set fire-front patch-set self ;; a new fire-front
    spread
  ]
end 

  
; Code for 'spread' procedure modified from code by George L.W. Perry, University of Auckland (http://web.env.auckland.ac.nz/people_profiles/perry_g/) 

to spread 
  
  while [ any? fire-front ]  ;; stop when we run out of fire-front
  [
    let new-fire-front patch-set nobody ;; empty set of patches for the next 'round' of the fire
    ask fire-front 
    [
      set pcolor red 
      let N neighbors with [ tsf > 0] 
      ask N
      [
        if random-float 1 <= pfs
        [
          set tsf 0
          set new-fire-front (patch-set new-fire-front self) ;; extend the next round front
        ]
      ]    
    set fire-front new-fire-front
    ]
  ]  
end     
      

There is only one version of this model, created over 11 years ago by James Millington.

Attached files

File Type Description Last updated
Feedback Loop Example: Wildland Fire Spread.png preview Preview for 'Feedback Loop Example: Wildland Fire Spread' almost 11 years ago, by James Millington Download

This model does not have any ancestors.

This model does not have any descendants.