Dark room

breed [students student]

students-own 
[
  user-id 
  step-size
  dark-region
  visible-region
]

to startup
  hubnet-reset
end 

to setup
  clear-patches
  clear-drawing
  clear-output
  
  color-patches
  
  ask turtles
  [
    set step-size 1
    update-vision    ;; update vision
    hubnet-send user-id "step-size" step-size
  ]
  reset-ticks
end 

to go
  listen-clients
  every 0.1
  [
    tick
  ]
end 

;;
;;  HubNet Procedure
;;

to listen-clients
  while [hubnet-message-waiting?]
  [
    hubnet-fetch-message
    ifelse hubnet-enter-message?
    [ create-new-student ]
    [
      ifelse hubnet-exit-message?
      [ remove-student ]
      [
        ask students with [user-id = hubnet-message-source] 
        [
          execute-command hubnet-message-tag 
          update-vision
        ]
      ]
    ]
  ]
end 

to create-new-student
  create-students 1
  [
    set user-id hubnet-message-source
    set label user-id
    set step-size 1
    update-vision
  ;  pen-down
    send-info-to-clients
  ]  
end 

to remove-student
  ask students with [user-id = hubnet-message-source]
  [die]
end 

to execute-command [command]
  if command = "step-size"
  [
    set step-size hubnet-message
    stop
  ]
    if command = "up"
  [ execute-move 0 stop ]
  if command = "down"
  [ execute-move 180 stop ]
  if command = "right"
  [ execute-move 90 stop ]
  if command = "left"
  [ execute-move 270 stop ]
end 

to send-info-to-clients
  hubnet-send user-id "location" (word "(" pxcor "," pycor ")")
end 

to execute-move [new-heading]
  set heading new-heading
  fd step-size
  send-info-to-clients
end 

to color-patches
  ask n-of 10 patches [set pcolor white]
end 

to update-vision
  set visible-region patches in-radius 5
  set dark-region patches with [not member? self [visible-region] of myself]
end 

to mask
  ask turtles [
    hubnet-clear-override user-id visible-region "pcolor" 
    hubnet-send-override user-id dark-region "pcolor" [black]
  ]
end