School gender discrimination

globals [primary-results secondary-results state-exams ]

breed [girls girl]
breed [boys boy]

turtles-own [ IQ knowledge primary-note secondary-note discrimination family-support own-compensation ] 

;;;;;;;;;;;
;  Setup  ;
;;;;;;;;;;;

to setup
  clear-all
  setup-class
  reset-ticks
end 

to setup-class
  let counter 0
  set-default-shape turtles "person"
    create-turtles 900 [
    set counter counter + 1
    let x floor (counter / 30)
    let y counter mod 30
    setxy (2 * x + 1) (2 * y + 1) 
    set size 2    
  ]
  ask turtles [
    ifelse random 2 > 0 [ 
      set breed boys 
      set color cyan
      set discrimination character-lottery "boy"
    ] 
    [ 
      set breed girls
      set color pink
      set discrimination character-lottery "girl"
    ]
    ; IQ is "inherent learning capacity" in this model.
    set IQ IQ-lottery
    if Show-IQ? [set label IQ]

    ; own ability to react to teachers' injustice
    set own-compensation reaction-lottery
    
    ; children born into supportive families are better off...
    set family-support family-lottery
  ]
end 

; IQ lottery at birth: gauss distribution of IQ around 100 with sigma = 15
; http://www.quora.com/What-does-the-distribution-of-IQ-scores-look-like

to-report IQ-lottery 
  report floor random-normal 100 15
end 

; Behaviour lottery at birth: will I be docile or defiant?
; remaining kids are neutral (not affected by discrimination.

to-report character-lottery [gender] 

  let lottery random 100
  let Defiant Defiant-boys
  let Docile Docile-boys
  if (gender = "girl") [
    set Defiant Defiant-girls
    set Docile Docile-girls
  ]
  if lottery < Defiant [ 
    set shape "wolf" 
    report Defiant-discrimination ]
  if (100 - lottery) < Docile [ 
    set shape "sheep" 
    report -1 * Defiant-discrimination ]
  report 0
end 


; Family lottery at birth: will I end up in a supportive or unsupportive family?
; Remaining kids are in neutral families

to-report family-lottery 
  let lottery random 100
  if lottery < Supportive [report Support-modifier]
  if (100 - lottery) < Discouraging [report -1 *  Support-modifier]
  report 0
end 

; Own reselience to injustice.
; It's propontial to Self-support-modifier, but modified by IQ because  
; the intelligent pupils have higher learning potential.
; TODO: the IQ modifier is probably too weak now.
; Note: we don't model the "I'm positively discriminated and therefore lazy" here.

to-report reaction-lottery 
   if discrimination > 0 [ report IQ / 100 * Self_support-modifier ]
   report 0
end 

;;;;;;;;;;;;;;;;;;;;:
; Support functions : 
;;;;;;;;;;;;;;;;;;;;:

; calcualte support by family
; all children with below-average score will receive support (positive or negative or zero) by family
; the value of (potential) family-support has already been determined at birth in family-lottery
; family support is more sucessful for kids with higher IQ
; both the knowledge and the final school notes are modified by the support modifier

to-report support-value [avg note]
  report ifelse-value (note < avg) [family-support * IQ / 100] [0] 
end 

; calculate own reaction to injustice. 
; the "compensation" equals change in knowledge and school note.

to-report  reaction-value
  if (discrimination = 0) [ report 0 ]
  ; remember - own-compensation depends on Self_support-modifier, see reaction lotery!
  report ifelse-value (discrimination > 0) [1] [-1] * own-compensation
end 


;;;;;;;;
; RUN  ;
;;;;;;;;

to go
  primary-notes
  if Slow-run? [wait 1]
  tick
  admission-secondary
  if Slow-run? [wait 1]
  tick
  secondary-notes
  if Slow-run? [wait 1]
  tick
  state-exam
  tick
;  graduate
;  tick
end 

to primary-notes
  ask turtles [
    set primary-note IQ - discrimination 
  ]
  let avg mean [primary-note] of turtles
  ask turtles [
    set primary-note primary-note + support-value avg primary-note + reaction-value
  ]
end 

to admission-secondary
  ask min-n-of ((100 - admission-rate) * count turtles / 100 )  turtles [primary-note] [
    set color black
    ;print (word "rejected (" who "): IQ=" IQ ", gender = " breed)
  ] 
end 

to secondary-notes
  ask turtles with [color != black ][
    set secondary-note IQ - discrimination 
  ]
  let avg mean [secondary-note] of turtles
  ask turtles with [color != black ] [
    set secondary-note secondary-note + reaction-value + support-value avg secondary-note
  ]
end 

to state-exam
  ask turtles with [color != black ] [
    ; At the end of the day, the the knowledge differs by value of the discrimination from the secondary note
    ; however, the knowledge has already been modified due to discrimination!
    set knowledge secondary-note + discrimination
  ]
end 

to graduate
  ask max-n-of ((admission-rate) / 100 * count turtles with [color != black]) turtles [knowledge] [
    ;set shape "graduated"
    set color ifelse-value (breed = girls) [red] [blue]
    set size 4
    ;print (word "graduated (" who "): IQ=" IQ ", gender = " breed)
  ] 
end