Femicides

1 collaborator

WHAT IS IT?

This model simulates the stalker behavior that a man can take against a woman in the society, even reaching a femicide in some cases.

The femicide is only the result of a long activity of harassment against a woman. Most cases caused by women that don’t perform public actions before the tragedy. There is statistics that shows a significant decrease of femicide probability when reporting properly.

HOW IT WORKS

This project considers two types of modeling, one model based on agents and the other one based on differential equations.

For both models four states are defined in which each woman can be. Those are:

Safety state(S): represent a woman that isn’t affected by any potential homicide.
Harassed state(Hw): represent a woman that is affected by one potential homicide.
Report state(R): represent a woman that is affected by one potential homicide but she made a public report.
Dead state(F): represent a femicide.

For man only two states are defined:

Wholesome (W): represent a man that doesn’t harass woman.
Potential homicide state (H): represent a man that harass and kill women.

We relate each of these states as follows

states

We also define probabilities of transition between the different states, which are:

HARASSMENT-TO-FEMICIDE-PROBABILITY (hf): Is the probability that a man who is harassing a woman murders her.
REPORTED-TO-FEMICIDE-PROBABILITY (rf): It is the probability that a report doesn’t work at all and the homicide is committed anyway.
HARASSMENT-PROBABILITY (h): The likelihood that a harassment will occur to a safety woman.
REPORTED-TO-SAFETY-PROBABILITY (rs): Is the likelihood that, after a woman made a report, can be saved thanks to police efficiency and become a safety woman again.
REPORT-HARASSMENT-PROBABILITY (rh): Represent the probability that a woman reports a harassment behavior by a man.
TURN-TO-HOMICIDE-PROBABILITY (th): The worst probability, here the model represents the likelihood of creation of a killer from a normal man.
TURN-TO-WHOLESOME-PROBABILITY (tw): As opposed to TURN-TO-HOMICIDE-PROBABILITY, the probability that a homicide will become a wholesome man.

Agent-based model

The model is initialized with a certain POPULATION of similar proportions of women and men.

Men agents

Men are represented initially with the blue color and their status are WHOLESOME. They can be turned into a POTENTIAL-MURDERER with a probability that it can changes manually. They are represented with the green color. On the other hand, the men can be turned into a WHOLESOME man with a probability that it can changes manually.

Women agents

Women are represented initially with the red color and their status are SAFETY. Changes in a woman's status depend on the interaction with men:

If a man with POTENTIAL-MURDERER status cross with a woman there are a probability that she can turned into:

HARASSED status represented by pink color(if her current status is SAFETY)
REPORTED status represented by yellow color(if her current status is HARASSED)
SAFETY status represented by blue color again(if her current status is REPORTED)
or just be killed from a HARASSED or REPORTED status and their agents just disappear.

Based in differential equations

Each of the states in which a woman or man can be are represented by a ‘stock’ on the Systems Dynamics Modeler and each equation establishes the transition from one state to another based on a probability. In the Systems Dynamics Modeler each transition can be represented with a ‘Flow’.

The equations are:

equations

Here we can see that the flows between each variable are represented by the transitions between each state, where there is a defined probability.

The basic idea is that for each equation (representing a state) there are inflows and outflows (except for femicides since there is no exit from this state), where, in the inputs, the probability is multiplied by the state from which it comes the flow and in the outputs, the probability is multiplied by the same state.

An exception occurs in the transition between the state 'S' and the state 'Hw' where, in addition to the probability h of harassment, we must take into account the percentage of homicides that exist, because if there are no homicides, this transition must be zero. We do this through the expression:

homicide-percentage

HOW TO USE IT

The total number of individuals in the simulation is controlled by the slider POPULATION (initialized to vary between 10–500), which must be set before SETUP is pushed.

Click the SETUP button to set up the agents. There are a random number of men and woman (blue and red agents respectively) and they are located on a random patch.

Click the GO to start the simulation. The agents will start to move on a similar direction simulating a typical walking of human behavior. Press GO button to stop the simulation and see the results.

Sliders: * POPULATION define the initial population. * REPORT-HARASSMENT-PROBABILITY: it changes the probability that a woman reports her harassment state. * REPORTED-TO-FEMICIDE-PROBABILITY: it changes the probability that a harassed woman who has reported, could be killed. * TURN-TO-FEMICIDE-PROBABILITY: it changes the probability that a man becomes a potential murderer.

The are some monitors to show some general data: * POTENCIAL-HOMICIDE-COUNTER * HARASSMENT COUNTER * REPORT COUNTER * FEMICIDE COUNTER * EFFECTIVE REPORTS * MEN NUMBER * WOMEN NUMBER

Finally there are two graphics which shows the change of states in women over time based on agent-based model and the differential equations model.

THINGS TO NOTICE

As time goes by, the female population is exponentially decreasing because of femicides that occur. But, as the probability of harassed women reporting increases, it can notice the huge decrease in total femicides. It may be obvious, since a report means less likelihood of the homicide being carried out. But, in our society, the probability of a woman reporting the harassment is extremely low, so the focus of this model is to be aware that reporting harassment is extremely important to avoid tragedies like this.

In other hand, as the probability of a man became a potential homicide, it can notice that a higher value implies a greater number of potential homicidal men, so more femicides will happen.

THINGS TO TRY

Try different values for %REPORT-HARASSMENT-PROBABILITY. How does the overall degree of femicides change?

Try different values for %REPORTED-TO-FEMICIDE-PROBABILITY. How much does police effectiveness really affect in cases of harassment? Does it really ensure the lives of women?

Try different values for %TURN-TO-FEMICIDE-PROBABILITY. How can a socially sexist or sick population affect the number of femicides?

Try different values of POPULATION. How does the initial occupancy density affect the number of femicides? How does it affect the time it takes for the model to finish?

EXTENDING THE MODEL

Based on the simplicity on this model when women change form ‘harassment state’ to ‘report state’. (a probability) It can be interesting to find out what are the reasons why a woman doesn’t report that she is suffering from harassment situations and incorporate them on the model. In this way the model could go deeper in terms of situations that women suffer in silence.

On the other hand, the probability that a man will become a homicide could be given by some factors that would also allow to go deeper and understand what is the cause and the possible actions that could be achieved to decrease this probability and, with it, the amount of femicides.

NETLOGO FEATURES

To simulate a human walking behavior, the agents move with a heading that changes between 10 and 20 respect its current heading.

CREDITS AND REFERENCES

To obtain some probabilities, we rely on information from Latin American news blogs that contain graphs showing the behavior of femicides in their respective countries:

‘Femicides 2017: 38% of the murdered women had denounced their aggressor’’ http://www.soychile.cl/Santiago/Sociedad/2017/09/10/486568/Femicidios-2017-38-habia-denunciado-contra-su-agresor-y-15-tenia-una-cautelar-vigente.aspx soychile.cl. Noticias locales de todas las regiones de Chile
‘Country by country: the map showing the tragic figures of femicides in Latin America’ http://www.bbc.com/mundo/noticias-america-latina-37828573 Noticias - BBC News Mundo - BBC.com
‘Latin America, the most violent region for women: there are at least 12 femicides a day’ https://www.nodal.am/2017/11/america-latina-la-region-mas-violenta-las-mujeres-al-menos-12-femicidios-diarios/ NODAL - Portal informativo de noticias de América Latina y el Caribe
‘Femicide in Chile: 2017 ends with more registered cases than last year’ http://www.emol.com/noticias/Nacional/2017/12/28/888956/Femicidios-en-Chile-El-2017-finaliza-con-mas-casos-que-el-ano-pasado.html Emol.com - El sitio de noticias online de Chile
’10 years of femicide in Argentina: definitions and figures of violence against women’ https://www.infobae.com/tendencias/2018/03/08/10-anos-de-femicidio-en-la-argentina-definiciones-y-cifras-de-la-violencia-contra-las-mujeres/ Infobae: Últimas Noticias de Argentina y del Mundo

Comments and Questions

Please start the discussion about this model! (You'll first need to log in.)

Click to Run Model

turtles-own[
  status ;; wholesome - homicide / safely - harrased - reported - femicide
  gender ;; man or woman
  age ;; between 0 and 80
  harassed-by ;;
]

globals[
  femicide-counter
  lifespan
  potencial-homicide-counter
  harassment-counter
  week-counter
  year
  total-male
  total-female
  last-femicide-counter
  last-report-counter
  total-reports
  effective-reports

  femicide-per-year
  femicides-average-per-year
  reports-per-year

  harassment-probability
  harassment-to-femicide-probability
  reported-to-safety-probability

  ;;turn-to-homicide-probability
  turn-to-wholesome-probability

]

to setup-constants
  set lifespan 80 * 52 ;; ages of life
  set harassment-probability 0.01
  set harassment-to-femicide-probability 0.01
  set reported-to-safety-probability 0.01

  set turn-to-wholesome-probability 0.01

  set femicide-counter 0
  set femicide-per-year 0
  set femicides-average-per-year 0
  set week-counter 0
  set year 0
  set total-male 0
  set total-female 0
  set last-femicide-counter 0
  set last-report-counter 0
  set total-reports 0
  set reports-per-year 0
  set effective-reports 0
  set harassment-counter 0
end 

to setup
  clear-all
  setup-constants
  setup-turtles
  reset-ticks
end 

to setup-turtles
  create-turtles population[
    setxy random-xcor random-ycor
    set age random lifespan / 52
    set harassed-by 0
    set shape "person"
    let rand random-float 1
    ifelse(rand < 0.5)[
      set gender "male"
      set color blue

      set status "wholesome"
    ][
      set gender "female"
      set color red

      set status "safety"
    ]
  ]
end 

to setupEc
  clear-plot
  system-dynamics-setup
end 

to goEc
  system-dynamics-go
  system-dynamics-do-plot
end 

to go
  move
  ask turtles[
    ;;get-older
    harassment
    harassment-to-femicide
    report-harassment
    reported-to-safety
    reported-to-femicide

    turn-to-homicide
    turn-to-wholesome

    count-gender
  ]
  update-global-variables
  tick
end 

to count-gender
  set total-male count turtles with [gender = "male"]
  set total-female count turtles with [gender = "female"]
end 

to inmigrate-people
  let i random-float 1
  if(i < 0.5)[
    create-turtles 1[
      setxy random-xcor random-ycor
      set age random lifespan / 52
      set shape "person"
      let rand random-float 1
      ifelse(rand < 0.5)[
        set gender "male"
        set color blue

        set status "wholesome"
      ][
        set gender "female"
        set color red

        set status "safety"
      ]
    ]
  ]
end 

to plot-femicides-per-year
  if plot-pen-exists? "femicides-per-year" and plot-pen-exists? "reports-per-year" [
    set-current-plot-pen "femicides-per-year"
    set week-counter week-counter + 1
    if(week-counter mod 52 = 0)[
      set year year + 1
      set femicide-per-year femicide-counter - last-femicide-counter
      set last-femicide-counter femicide-counter
      plotxy ticks femicide-per-year

      set reports-per-year total-reports - last-report-counter
      set last-report-counter total-reports
      set-current-plot-pen "reports-per-year"
      plotxy ticks reports-per-year

      set femicides-average-per-year femicide-counter / (year)
      set-current-plot-pen "homicides-per-year"
      plotxy ticks potencial-homicide-counter
      ;;plot femicides-average-per-year
    ]
  ]
end 

to harassment
  let s-to-h random-float 1 ;; S to H
  let node one-of other turtles in-radius 2.0 with [ gender = "male" AND status = "potencial-femicide"]
  let potencial-femicide-id 0

  if ( node != nobody) [
    ask node[
      set potencial-femicide-id who
    ]
    if(s-to-h < harassment-probability AND status = "safety" AND gender = "female")[
      set status "harassed"
      set harassed-by potencial-femicide-id
      set color pink
    ]
  ]
end 

to harassment-to-femicide
  let hw-to-f random-float 1
  let node one-of other turtles in-radius 2.0 with [ gender = "male" AND status ="potencial-femicide"]
  if ( node != nobody) [
    if(hw-to-f < harassment-to-femicide-probability AND status = "harassed" AND gender = "female")[
      set femicide-counter femicide-counter + 1
      die
    ]
  ]
end 

to report-harassment
  let hw-to-r random-float 1
  if(hw-to-r < report-harassment-probability AND status = "harassed" AND gender = "female")[
    set status "reported"
    set color yellow
    set total-reports total-reports + 1
  ]
end 

to reported-to-femicide
  let r-to-f random-float 1
  let node one-of other turtles in-radius 2.0 with [ gender = "male" AND status = "potencial-femicide"]
  if ( node != nobody) [
    if(r-to-f < reported-to-femicide-probability AND status = "reported" AND gender = "female")[
      set femicide-counter femicide-counter + 1
      die
    ]
  ]
end 

to reported-to-safety
  let r-to-s random-float 1
  if ( r-to-s < reported-to-safety-probability AND status = "reported" )
  [
    set harassed-by 0
    set status "safety"
    set color red
    set effective-reports effective-reports + 1
  ]
end 

to turn-to-homicide
  let rand random-float 1
  if(rand < turn-to-homicide-probability AND gender = "male")[
    set status "potencial-femicide"
    set color green
  ]
end 

to turn-to-wholesome
  let rand random-float 1
  if(rand < turn-to-wholesome-probability AND gender = "male")[
   set status "wholesome"
   set color blue
  ]
end 

to update-global-variables
  set potencial-homicide-counter count turtles with [color = green]
  set harassment-counter count turtles with [status = "harassed"]
end 

to get-older
  set age age + (1 / 52)
  if age > lifespan / 52 [ die ]
end 

to move
  repeat 5[
    ask turtles[
      fd 0.2
    ]

    display
  ]
end

There is only one version of this model, created over 7 years ago by Daniel Molina.

Attached files

File	Type	Description	Last updated
Femicides.png	preview	Preview for 'Femicides'	over 7 years ago, by Daniel Molina	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo